SUBROUTINE PLOTU(X,N)
C
C     PURPOSE--THIS SUBROUTINE PRODUCES THE FOLLOWING 4 PLOTS--
C              ALL ON THE SAME PRINTER PAGE--
C              1) DATA PLOT--X(I) VERSUS I
C              2) AUTOREGRESSION PLOT--X(I) VERSUS X(I-1)
C              3) HISTOGRAM
C              4) NORMAL PROBABILITY PLOT
C              IN ADDITION, LOCATION, SCALE, AND AUTOCORRELATION
C              SUMMARY STATISTICS ARE PRINTED OUT AUTOMATICALLY
C              ON THE SAME PAGE.
C              THESE PLOTS GIVE THE DATA ANALYST A QUICK
C              FIRST-PASS CHECK AT SOME OF
C              THE UNDERLYING ASSUMPTIONS TYPICALLY MADE--
C              CONSTANT LOCATION, CONSTANT SCALE, NO OUTLIERS,
C              UNAUTOCORRELATED DATA, SYMMETRY, NORMALITY.
C     INPUT ARGUMENTS--X      = THE SINGLE PRECISION VECTOR OF
C                               (UNSORTED) OBSERVATIONS.
C                      N      = THE INTEGER NUMBER OF OBSERVATIONS
C                               IN THE VECTOR X.
C     OUTPUT--4 PLOTS (ALL ON THE SAME PRINTER PAGE)--
C             1) DATA PLOT--X(I) VERSUS I
C             2) AUTOREGRESSION PLOT--X(I) VERSUS X(I-1)
C             3) HISTOGRAM
C             4) NORMAL PROBABILITY PLOT
C             PLUS LOCATION, SCALE, AND 
C             AUTOCORRELATION SUMMARY STATISTICS. 
C     PRINTING--YES 
C     RESTRICTIONS--THE MINIMUM ALLOWABLE VALUE OF N
C                   FOR THIS SUBROUTINE IS 2.
C                 --THE MAXIMUM ALLOWABLE VALUE OF N
C                   FOR THIS SUBROUTINE IS 7500.
C     OTHER DATAPAC   SUBROUTINES NEEDED--SORT, UNIMED, NORPPF.
C     FORTRAN LIBRARY SUBROUTINES NEEDED--SQRT.
C     MODE OF INTERNAL OPERATIONS--SINGLE PRECISION
C     LANGUAGE--ANSI FORTRAN. 
C     REFERENCES--FILLIBEN, 'SOME USEFUL COMPUTERIZED TECHNIQUES
C                 FOR DATA ANALYSIS', (UNPUBLISHED MANUSCRIPT
C                 AVAILABLE FROM AUTHOR), 1975.
C               --HAHN AND SHAPIRO, STATISTICAL METHODS IN ENGINEERING,
C                 1967, PAGES 260-308.
C               --FILLIBEN, 'THE PROBABILITY PLOT CORRELATION COEFFICIENT
C                 TEST FOR NORMALITY', TECHNOMETRICS, 1975, PAGES 111-117.
C     WRITTEN BY--JAMES J. FILLIBEN
C                 STATISTICAL ENGINEERING LABORATORY (205.03)
C                 NATIONAL BUREAU OF STANDARDS
C                 WASHINGTON, D. C. 20234
C                 PHONE--301-921-2315
C     ORIGINAL VERSION--NOVEMBER  1974. 
C     UPDATED         --JANUARY   1975. 
C     UPDATED         --NOVEMBER  1975. 
C     UPDATED         --FEBRUARY  1976. 
C     UPDATED         --MAY       1976. 
C     UPDATED         --FEBRUARY  1977. 
C
C---------------------------------------------------------------------
C
      CHARACTER*4 IGRAPH
      CHARACTER*4 BLANK,HYPHEN,ALPHAI,ALPHAX
      CHARACTER*4 ALPHAM,ALPHAA,ALPHAD,ALPHAN,EQUAL
C
      DIMENSION X(1)
      DIMENSION X2(7500),Y2(7500)
      DIMENSION YLABLE(45,4)
      DIMENSION XMIN(4),XMAX(4),XMID(4),X25(4),X75(4)
      DIMENSION ITAXIS(4),IBAXIS(4),ILAXIS(4),IRAXIS(4)
      COMMON /BLOCK1/ IGRAPH(55,130)
      COMMON /BLOCK2/ WS(15000)
CCCCC COMMON IGRAPH(45,110)
      EQUIVALENCE (X2(1),WS(1)),(Y2(1),WS(7501))
C
      DATA BLANK,HYPHEN,ALPHAI,ALPHAX/' ','-','I','X'/
      DATA ALPHAM,ALPHAA,ALPHAD,ALPHAN,EQUAL/'M','A','D','N','='/
      DATA ITAXIS(1),IBAXIS(1),ILAXIS(1),IRAXIS(1)/ 1,19,5,49/
      DATA ITAXIS(2),IBAXIS(2),ILAXIS(2),IRAXIS(2)/ 1,19,54,98/
      DATA ITAXIS(3),IBAXIS(3),ILAXIS(3),IRAXIS(3)/27,45,5,49/
      DATA ITAXIS(4),IBAXIS(4),ILAXIS(4),IRAXIS(4)/ 27,45,54,98/
C
      IPR=6
      ILOWER=2
      IUPPER=7500
C
C     CHECK THE INPUT ARGUMENTS FOR ERRORS
C
      WRITE(IPR,998)
      IF(N.LT.ILOWER.OR.N.GT.IUPPER)GOTO50
      HOLD=X(1)
      DO60I=2,N
      IF(X(I).NE.HOLD)GOTO90
   60 CONTINUE
      WRITE(IPR, 9)HOLD
      RETURN
   50 WRITE(IPR,17)ILOWER,IUPPER
      WRITE(IPR,47)N
      RETURN
   90 CONTINUE
    9 FORMAT(1H ,   '***** FATAL ERROR--THE FIRST  INPUT ARGUMENT (A VEC
     1TOR) TO THE PLOTU  SUBROUTINE HAS ALL ELEMENTS = ',E15.8,
     1' *****')
   17 FORMAT(1H ,   '***** FATAL ERROR--THE SECOND INPUT ARGUMENT TO THE
     1 PLOTU  SUBROUTINE IS OUTSIDE THE ALLOWABLE (',I1,',',I6, ') INTER
     1VAL *****')
   47 FORMAT(1H , '***** THE VALUE OF THE ARGUMENT IS ',I8   ,' *****')
C
C-----START POINT-----------------------------------------------------
C
C     PRODUCE THE FIRST PLOT (UPPER LEFT)--X(I) VERSUS I
C
C     DETERMINE THE VERTICAL AXIS VECTOR Y2, THE HORIZONTAL 
C     AXIS VECTOR X2, AND THE PLOT SAMPLE SIZE N2 FOR THIS
C     PARTICUAR PLOT.
C
      N2=N
      DO100I=1,N2
      Y2(I)=X(I)
      X2(I)=I
  100 CONTINUE
C
      IPLOT=1
      GOTO5000
C
C*********************************************************************
C
C     PRODUCE THE SECOND PLOT (UPPER RIGHT)--X(I) VERSUS X(I-1)
C
C     DETERMINE THE VERTICAL AXIS VECTOR Y2, THE HORIZONTAL 
C     AXIS VECTOR X2, AND THE PLOT SAMPLE SIZE N2 FOR THIS
C     PARTICULAR PLOT.
C
 2000 N2=N-1
      DO1100I=1,N2
      IP1=I+1
      Y2(I)=X(IP1)
      X2(I)=X(I)
 1100 CONTINUE
C
      IPLOT=2
      GOTO5000
C
C*********************************************************************
C
C     PRODUCE THE THIRD PLOT (LOWER LEFT)-A HISTOGRAM
C
 3000 N2=41
      INC=3
C
C     COMPUTE THE SAMPLE MEAN AND SAMPLE STANDARD DEVIATION 
C
      AN=N
      SUM=0.0
      DO3100I=1,N
      SUM=SUM+X(I)
 3100 CONTINUE
      XMEAN=SUM/AN
      SUM=0.0
      DO 3200I=1,N
      SUM=SUM+(X(I)-XMEAN)**2 
 3200 CONTINUE
      S=SQRT(SUM/(AN-1.0))
C
C     FORM THE FREQUENCY TABLE (Y2) WHICH CORRESPONDS TO A HISTOGRAM
C     WITH 41 CLASSES AND A CLASS WIDTH OF THREE TENTHS OF A SAMPLE STANDARD
C     DEVIATION.
C
      DO3300I=1,41
      Y2(I)=0.0
 3300 CONTINUE
C
      NUMOUT=0
      DO3400I=1,N
      Z=(X(I)-XMEAN)/S
      IF(-6.0.LE.Z.AND.Z.LE.6.0)GOTO3450
      NUMOUT=NUMOUT+1
      GOTO3400
 3450 CONTINUE
      MT=((Z+6.0)/0.3)+1.5
      Y2(MT)=Y2(MT)+1.0
 3400 CONTINUE
C
      DO3800I=1,41
      AI=I
      X2(I)=XMEAN+((AI-21.0)*0.3)*S
 3800 CONTINUE
C
      NUMCLA=41
      CWIDSD=0.3
      CWIDTH=CWIDSD*S
C
      IPLOT=3
      GOTO5000
C
C*********************************************************************
C
C     PRODUCE THE FOURTH PLOT (LOWER RIGHT)--A NORMAL PROBABILITY PLOT
C
C     DETERMINE THE VERTICAL AXIS VECTOR Y2, THE HORIZONTAL 
C     AXIS VECTOR X2, AND THE PLOT SAMPLE SIZE N2 FOR THIS
C     PARTICUAR PLOT.
C
 4000 N2=N
      CALL SORT(X,N,Y2)
      CALL UNIMED(N,X2)
      DO4100I=1,N
      CALL NORPPF(X2(I),X2(I))
 4100 CONTINUE
C
      IPLOT=4
      GOTO5000
C
C
C*********************************************************************
C
C     OPERATE ON A PARTICULAR PLOT
C
 5000 ITAX=ITAXIS(IPLOT)
      IBAX=IBAXIS(IPLOT)
      ILAX=ILAXIS(IPLOT)
      IRAX=IRAXIS(IPLOT)
C
      ITAXP2=ITAX+2 
      IBAXM2=IBAX-2 
      ILAXP2=ILAX+2 
      IRAXM2=IRAX-2 
      ILAXM4=ILAX-4 
      ILAXM3=ILAX-3 
      ILAXM2=ILAX-2 
      ILAXM1=ILAX-1 
      IYMID=(ITAXP2+IBAXM2)/2 
      IXMID=(ILAXP2+IRAXM2)/2 
      HEIGHT=IBAXM2-ITAXP2
      WIDTH=IRAXM2-ILAXP2
C
C     BLANK OUT THE GRAPH
C
      DO300I=ITAX,IBAX
      DO350J=ILAXM4,IRAX
      IGRAPH(I,J)=BLANK
  350 CONTINUE
  300 CONTINUE
C
C     PRODUCE THE Y AXIS
C
      DO400I=ITAXP2,IBAXM2
      IGRAPH(I,ILAX)=ALPHAI
      IGRAPH(I,IRAX)=ALPHAI
  400 CONTINUE
      IYDEL=(IBAXM2-ITAXP2)/2 
      DO450I=ITAXP2,IBAXM2,IYDEL
      IGRAPH(I,ILAX)=HYPHEN
      IGRAPH(I,IRAX)=HYPHEN
  450 CONTINUE
      IGRAPH(ITAXP2,ILAXM4)=EQUAL
      IGRAPH(ITAXP2,ILAXM3)=ALPHAM
      IGRAPH(ITAXP2,ILAXM2)=ALPHAA
      IGRAPH(ITAXP2,ILAXM1)=ALPHAX
      IGRAPH(IYMID,ILAXM4)=EQUAL
      IGRAPH(IYMID,ILAXM3)=ALPHAM
      IGRAPH(IYMID,ILAXM2)=ALPHAI
      IGRAPH(IYMID,ILAXM1)=ALPHAD
      IGRAPH(IBAXM2,ILAXM4)=EQUAL
      IGRAPH(IBAXM2,ILAXM3)=ALPHAM
      IGRAPH(IBAXM2,ILAXM2)=ALPHAI
      IGRAPH(IBAXM2,ILAXM1)=ALPHAN
C
C     PRODUCE THE X AXIS
C
      DO500J=ILAXP2,IRAXM2
      IGRAPH(ITAX,J)=HYPHEN
      IGRAPH(IBAX,J)=HYPHEN
  500 CONTINUE
      IXDEL=(IRAXM2-ILAXP2)/4 
      DO550J=ILAXP2,IRAXM2,IXDEL
      IGRAPH(ITAX,J)=ALPHAI
      IGRAPH(IBAX,J)=ALPHAI
  550 CONTINUE
C
C     DETERMINE THE VALUES TO BE LISTED ON THE LEFT VERTICAL AXIS
C
      YMIN=Y2(1)
      YMAX=Y2(1)
      DO600I=1,N2
      IF(Y2(I).LT.YMIN)YMIN=Y2(I)
      IF(Y2(I).GT.YMAX)YMAX=Y2(I)
  600 CONTINUE
      IF(IPLOT.EQ.3)YMIN=1.0
      DO650I=ITAXP2,IBAXM2
      ANUM=I-ITAXP2 
      YLABLE(I,IPLOT)=YMAX-(ANUM/HEIGHT)*(YMAX-YMIN)
  650 CONTINUE
C
C     DETERMINE XMIN, XMAX, XMID, X25 (=THE 25% POINT), AND 
C     X75 (=THE 75% POINT)
C
      XMIN2=X2(1)
      XMAX2=X2(1)
      DO700I=1,N2
      IF(X2(I).LT.XMIN2)XMIN2=X2(I)
      IF(X2(I).GT.XMAX2)XMAX2=X2(I)
  700 CONTINUE
      XMIN(IPLOT)=XMIN2
      XMAX(IPLOT)=XMAX2
      XMID(IPLOT)=(XMIN2+XMAX2)/2.0
      X25(IPLOT)=0.75*XMIN2+0.25*XMAX2
      X75(IPLOT)=0.25*XMIN2+0.75*XMAX2
C
C     DETERMINE THE (X,Y) PLOT POSITIONS
C
      RATIOY=0.0
      RATIOX=0.0
      IF(YMAX.GT.YMIN)RATIOY=HEIGHT/(YMAX-YMIN)
      IF(XMAX(IPLOT).GT.XMIN(IPLOT))RATIOX=
     1WIDTH/(XMAX(IPLOT)-XMIN(IPLOT))
      IF(IPLOT.EQ.3)GOTO750
      DO800I=1,N2
      MX=RATIOX*(X2(I)-XMIN(IPLOT))+0.5 
      MX=MX+ILAXP2
      MY=RATIOY*(Y2(I)-YMIN)+0.5
      MY=IBAXM2-MY
      IGRAPH(MY,MX)=ALPHAX
  800 CONTINUE
      GOTO850
C
  750 DO900I=1,N2
      IF(Y2(I).LE.0.5)GOTO900 
      MX=RATIOX*(X2(I)-XMIN(IPLOT))+0.5 
      MX=MX+ILAXP2
      MY=RATIOY*(Y2(I)-YMIN)+0.5
      MY=IBAXM2-MY
      IGRAPH(MY,MX)=ALPHAX
      DO950IY=MY,IBAXM2
      IGRAPH(IY,MX)=ALPHAX
  950 CONTINUE
  900 CONTINUE
C
  850 IF(IPLOT.EQ.1)GOTO2000
      IF(IPLOT.EQ.2)GOTO3000
      IF(IPLOT.EQ.3)GOTO4000
C
C******************************************************************** 
C
C     COMPUTE SUMMARY STATISTICS
C
      ZMIN=Y2(1)
      ZMAX=Y2(N)
      ZRANGE=ZMAX-ZMIN
      ZMEAN=XMEAN
      ZSD=S
      ZDEVB=ZMEAN-ZMIN
      ZRDEVB=0.0
      IF(ZMEAN.NE.0.0)ZRDEVB=100.0*ZDEVB/ZMEAN
      IF(ZRDEVB.LT.0.0)ZRDEVB=-ZRDEVB
      ZDEVA=ZMAX-ZMEAN
      ZRDEVA=0.0
      IF(ZMEAN.NE.0.0)ZRDEVA=100.0*ZDEVA/ZMEAN
      IF(ZRDEVA.LT.0.0)ZRDEVA=-ZRDEVA
C
C     DETERMINE THE NUMBER OF DISTINCT POINTS
C
      NUMDIS=1
      NM1=N-1
      DO7200I=1,NM1 
      IP1=I+1
      IF(Y2(I).EQ.Y2(IP1))GOTO7200
      NUMDIS=NUMDIS+1
 7200 CONTINUE
C
C     COMPUTE THE SAMPLE MEDIAN
C
      NHALF=N/2
      IEVODD=N-2*(N/2)
      IF(IEVODD.EQ.0)GOTO7250 
      ZMED=Y2(NHALF)
      GOTO7260
 7250 NHALFP=NHALF+1
      ZMED=(Y2(NHALF)+Y2(NHALFP))/2.0
 7260 CONTINUE
C
C     DETERMINE THE FREQUENCY OF THE SAMPLE MIN AND MAX
C
      NUMMIN=1
      NM1=N-1
      DO7400I=1,NM1 
      IP1=I+1
      IF(Y2(I).EQ.Y2(IP1))NUMMIN=NUMMIN+1
      IF(Y2(I).EQ.Y2(IP1))GOTO7400
      GOTO7450
 7400 CONTINUE
 7450 NUMMAX=1
      DO7500I=1,NM1 
      IREV=N-I+1
      NMI=N-I
      IF(Y2(IREV).EQ.Y2(NMI))NUMMAX=NUMMAX+1
      IF(Y2(IREV).EQ.Y2(NMI))GOTO7500
      GOTO7550
 7500 CONTINUE
 7550 CONTINUE
      PROMIN=NUMMIN 
      PROMIN=100.0*PROMIN/AN
      PROMAX=NUMMAX 
      PROMAX=100.0*PROMAX/AN
C
C     COMPUTE THE AUTOCORRELATION
C
      ZMEAN1=(AN*ZMEAN-X(N))/(AN-1.0)
      ZMEAN2=(AN*ZMEAN-X(1))/(AN-1.0)
      SUM1=0.0
      SUM2=0.0
      SUM3=0.0
      NM1=N-1
      DO7600I=1,NM1 
      IP1=I+1
      SUM1=SUM1+(X(I)-ZMEAN1)*(X(IP1)-ZMEAN2)
      SUM2=SUM2+(X(I)-ZMEAN1)**2
      SUM3=SUM3+(X(IP1)-ZMEAN2)**2
 7600 CONTINUE
      SUM23=SUM2*SUM3
      ZAUTOC=9999.99
      IF(SUM23.GT.0.0)ZAUTOC=SUM1/(SQRT(SUM23))
      ZAUTOC=100.0*ZAUTOC
C
C     WRITE EVERYTHING OUT
C
      ITAX=ITAXIS(1)
      IBAX=IBAXIS(1)
      ITAXP1=ITAX+1 
      ITAXP2=ITAX+2 
      IBAXM1=IBAX-1 
      IBAXM2=IBAX-2 
      J1=ILAXIS(1)-4
      J2=IRAXIS(1)
      J3=ILAXIS(2)-4
      J4=IRAXIS(2)
      WRITE(IPR,5104)
      WRITE(IPR,5105)(IGRAPH(ITAX,J),J=J1,J2),(IGRAPH(ITAX,J),J=J3,J4)
      WRITE(IPR,5105)(IGRAPH(ITAXP1,J),J=J1,J2),(IGRAPH(ITAXP1,J),J=J3,J
     14)
      DO5100I=ITAXP2,IBAXM2
      WRITE(IPR,5110)YLABLE(I,1),(IGRAPH(I,J),J=J1,J2),
     1               YLABLE(I,2),(IGRAPH(I,J),J=J3,J4)
 5100 CONTINUE
      WRITE(IPR,5105)(IGRAPH(IBAXM1,J),J=J1,J2),(IGRAPH(IBAXM1,J),J=J3,J
     14)
      WRITE(IPR,5105)(IGRAPH(IBAX,J),J=J1,J2),(IGRAPH(IBAX,J),J=J3,J4)
      WRITE(IPR,5115)XMIN(1),X25(1),XMID(1),X75(1),XMAX(1), 
     1               XMIN(2),X25(2),XMID(2),X75(2),XMAX(2)
C
      ISKIPM=2
      DO5200I=1,ISKIPM
      WRITE(IPR,999)
 5200 CONTINUE
C
      ITAX=ITAXIS(3)
      IBAX=IBAXIS(3)
      ITAXP1=ITAX+1 
      ITAXP2=ITAX+2 
      IBAXM1=IBAX-1 
      IBAXM2=IBAX-2 
      J1=ILAXIS(3)-4
      J2=IRAXIS(3)
      J3=ILAXIS(4)-4
      J4=IRAXIS(4)
      WRITE(IPR,5304)
      WRITE(IPR,5105)(IGRAPH(ITAX,J),J=J1,J2),(IGRAPH(ITAX,J),J=J3,J4)
      WRITE(IPR,5105)(IGRAPH(ITAXP1,J),J=J1,J2),(IGRAPH(ITAXP1,J),J=J3,J
     14)
      DO5300I=ITAXP2,IBAXM2
      WRITE(IPR,5110)YLABLE(I,3),(IGRAPH(I,J),J=J1,J2),
     1               YLABLE(I,4),(IGRAPH(I,J),J=J3,J4)
 5300 CONTINUE
      WRITE(IPR,5105)(IGRAPH(IBAXM1,J),J=J1,J2),(IGRAPH(IBAXM1,J),J=J3,J
     14)
      WRITE(IPR,5105)(IGRAPH(IBAX,J),J=J1,J2),(IGRAPH(IBAX,J),J=J3,J4)
      WRITE(IPR,5115)XMIN(3),X25(3),XMID(3),X75(3),XMAX(3), 
     1               XMIN(4),X25(4),XMID(4),X75(4),XMAX(4)
      WRITE(IPR,5320)
      WRITE(IPR,5325)NUMCLA,N,NUMDIS
      WRITE(IPR,5326)CWIDTH,CWIDSD,ZMIN,NUMMIN,PROMIN
      WRITE(IPR,5330)NUMOUT,ZMED
      WRITE(IPR,5331)ZMEAN
      WRITE(IPR,5332)ZMAX,NUMMAX,PROMAX 
      WRITE(IPR,5334)ZSD,ZRANGE
      WRITE(IPR,5336)ZDEVB,ZRDEVB
      WRITE(IPR,5338)ZDEVA,ZRDEVA
      WRITE(IPR,5340)ZAUTOC
C
 5104 FORMAT(1H ,20X,12X,'PLOT OF X(I) VERSUS I',41X,'PLOT OF ',
     1 'X(I) VERSUS X(I-1)')
 5105 FORMAT(1H ,16X,4A1,45A1,16X,4A1,45A1)
 5110 FORMAT(1H ,F16.7,4A1,45A1,F16.7,4A1,45A1)
 5115 FORMAT(1H ,17X,5F10.4,15X,4F10.4,F9.3)
 5304 FORMAT(1H ,38X,'HISTOGRAM',49X,'NORMAL PROBABILITY PLOT')
 5320 FORMAT(1H ,20X,' -6        -3         0         3         6')
 5325 FORMAT(1H ,20X,'NUMBER OF CLASSES = ',I3,42X,
     1'SAMPLE SIZE =',I9,' DISTINCT POINTS =',I6) 
 5326 FORMAT(1H ,20X,'CLASS WIDTH = ',E14.7,' = ',F3.1,
     1 ' STANDARD DEVIATIONS',11X,
     1'MINIMUM =',F13.6,' COUNT =',I5,' (',F7.2,'%)')
 5330 FORMAT(1H ,16X,I5,' OBSERVATIONS WERE IN EXCESS OF 6 STANDARD', 
     1 ' DEVIATIONS',11X,
     1'MEDIAN =',F14.6)
 5331 FORMAT(1H ,20X,  'ABOUT THE SAMPLE MEAN AND SO WERE NOT PRINTED IN
     1 HISTOGRAM',7X,
     1'MEAN =',F16.6)
 5332 FORMAT(1H ,85X,
     1'MAXIMUM =',F13.6,' COUNT =',I5,' (',F7.2,'%)')
 5334 FORMAT(1H ,85X,
     1'ST. DEV. =',F12.6,' RANGE =',F16.6)
 5336 FORMAT(1H ,20X,65X,'MAX DEV. BELOW MEAN =',F14.6,' (',F7.2,'%)')
 5338 FORMAT(1H ,85X,'MAX DEV. ABOVE MEAN =',F14.6,' (',F7.2,'%)')
 5340 FORMAT(1H ,85X,'AUTOCORR. =',F10.2,'%')
  998 FORMAT(1H1)
  999 FORMAT(1H )
C
      RETURN
      END